複素線形方程式: パック形式の対称行列 : (右辺は行列)

LAPACKサンプルソースコード : 使用ルーチン名：ZSPSVX

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > パック形式の対称行列

概要

本サンプルはFortran言語によりLAPACKルーチンZSPSVXを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A X = B, \end{displaymath}

$ A$は複素対称行列です。

\begin{displaymath} A = \left( \begin{array}{cccc} -0.56 + 0.12 i & -1.54 - 2... ...- 2.96 i & 5.14 - 0.64 i & -0.39 - 0.71 i \end{array} \right) \end{displaymath}

及び

\begin{displaymath} B = \left( \begin{array}{cc} -6.43 + 19.24 i & -4.59 - 35... ...\\ -55.64 + 41.22 i & -19.09 - 35.97 i \end{array} \right). \end{displaymath}

解のエラー推定値、行列$ A$の条件数の逆数の推定値も合わせて出力されます。

入力データ

（本ルーチンの詳細はZSPSVX のマニュアルページを参照）
このデータをダウンロード 
ZSPSVX Example Program Data
    4               2                                            :N and NRHS
 ( -0.56,  0.12) ( -1.54, -2.86) (  5.32, -1.59) (  3.80,  0.92)
                 ( -2.83 ,-0.03) ( -3.52,  0.58) ( -7.86, -2.96)
                                 (  8.86,  1.81) (  5.14, -0.64)
                                                 ( -0.39 ,-0.71) :End matrix A
 ( -6.43, 19.24) ( -4.59,-35.53)
 ( -0.49, -1.47) (  6.95, 20.49)
 (-48.18, 66.00) (-12.08,-27.02)
 (-55.64, 41.22) (-19.09,-35.97)                                 :End matrix B

出力結果

（本ルーチンの詳細はZSPSVX のマニュアルページを参照）
この出力例をダウンロード 
 ZSPSVX Example Program Results

 Solution(s)
                    1                 2
 1  (-4.0000, 3.0000) (-1.0000, 1.0000)
 2  ( 3.0000,-2.0000) ( 3.0000, 2.0000)
 3  (-2.0000, 5.0000) ( 1.0000,-3.0000)
 4  ( 1.0000,-1.0000) (-2.0000,-1.0000)

 Backward errors (machine-dependent)
       8.1E-17    3.0E-17

 Estimated forward error bounds (machine-dependent)
       1.2E-14    1.2E-14

 Estimate of reciprocal condition number
       4.9E-02

ソースコード

（本ルーチンの詳細はZSPSVX のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zspsvx_example

!     ZSPSVX Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zspsvx
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
      Character (1), Parameter :: uplo = 'U'
!     .. Local Scalars ..
      Real (Kind=dp) :: rcond
      Integer :: i, ifail, info, j, ldb, ldx, n, nrhs
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: afp(:), ap(:), b(:, :), work(:), &
        x(:, :)
      Real (Kind=dp), Allocatable :: berr(:), ferr(:), rwork(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZSPSVX Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      ldb = n
      ldx = n
      Allocate (afp((n*(n+1))/2), ap((n*(n+1))/2), b(ldb,nrhs), work(2*n), x( &
        ldx,nrhs), berr(nrhs), ferr(nrhs), rwork(n), ipiv(n))

!     Read the upper or lower triangular part of the matrix A from
!     data file

      If (uplo=='U') Then
        Read (nin, *)((ap(i+(j*(j-1))/2),j=i,n), i=1, n)
      Else If (uplo=='L') Then
        Read (nin, *)((ap(i+((2*n-j)*(j-1))/2),j=1,i), i=1, n)
      End If

!     Read B from data file

      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Solve the equations AX = B for X
      Call zspsvx('Not factored', uplo, n, nrhs, ap, afp, ipiv, b, ldb, x, &
        ldx, rcond, ferr, berr, work, rwork, info)

      If ((info==0) .Or. (info==n+1)) Then

!       Print solution, error bounds and condition number

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
          x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
          'Integer', clabs, 80, 0, ifail)

        Write (nout, *)
        Write (nout, *) 'Backward errors (machine-dependent)'
        Write (nout, 100) berr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
        Write (nout, 100) ferr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimate of reciprocal condition number'
        Write (nout, 100) rcond
        Write (nout, *)

        If (info==n+1) Then
          Write (nout, *)
          Write (nout, *) 'The matrix A is singular to working precision'
        End If
      Else
        Write (nout, 110) 'The diagonal block ', info, ' of D is zero'
      End If

100   Format ((3X,1P,7E11.1))
110   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks