複素線形方程式: エルミート正定値三重対角行列 : (右辺は行列)

LAPACKサンプルソースコード : 使用ルーチン名：ZPTSVX

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > エルミート正定値三重対角行列

概要

本サンプルはFortran言語によりLAPACKルーチンZPTSVXを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A x = b, \end{displaymath}

$ A$はエルミート正定値三重対角行列です。

\begin{displaymath} A = \left( \begin{array}{ccccc} 16.0 & 16.0 - 16.0 i & 0 ... ...0 + 4.0 i \\ 0 & 0 & 1.0 - 4.0 i & 21.0 \end{array} \right) \end{displaymath}

及び

\begin{displaymath} b = \left( \begin{array}{rr} 64.0 + 16.0 i & -16.0 - 32.0... ...4.0 i \\ 14.0 - 27.0 i & 35.0 + 15.0 i \end{array} \right). \end{displaymath}

解のエラー推定値、$ A$の条件数の逆数の推定値も合わせて出力されます。

入力データ

（本ルーチンの詳細はZPTSVX のマニュアルページを参照）
このデータをダウンロード 
ZPTSVX Example Program Data
    4             2                               :Values of N and NRHS
   16.0          41.0          46.0          21.0 :End of diagonal D
 ( 16.0, 16.0) ( 18.0, -9.0) (  1.0, -4.0)        :End of sub-diagonal E
 ( 64.0, 16.0) (-16.0,-32.0)
 ( 93.0, 62.0) ( 61.0,-66.0)
 ( 78.0,-80.0) ( 71.0,-74.0)
 ( 14.0,-27.0) ( 35.0, 15.0)                      :End of matrix B

出力結果

（本ルーチンの詳細はZPTSVX のマニュアルページを参照）
この出力例をダウンロード 
 ZPTSVX Example Program Results

 Solution(s)
                    1                 2
 1  ( 2.0000, 1.0000) (-3.0000,-2.0000)
 2  ( 1.0000, 1.0000) ( 1.0000, 1.0000)
 3  ( 1.0000,-2.0000) ( 1.0000,-2.0000)
 4  ( 1.0000,-1.0000) ( 2.0000, 1.0000)

 Backward errors (machine-dependent)
     0.0E+00    0.0E+00

 Estimated forward error bounds (machine-dependent)
     9.0E-12    6.1E-12

 Estimate of reciprocal condition number
     1.1E-04

ソースコード

（本ルーチンの詳細はZPTSVX のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zptsvx_example

!     ZPTSVX Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zptsvx
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=dp) :: rcond
      Integer :: i, ifail, info, ldb, ldx, n, nrhs
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: b(:, :), e(:), ef(:), work(:), x(:, :)
      Real (Kind=dp), Allocatable :: berr(:), d(:), df(:), ferr(:), rwork(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZPTSVX Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      ldb = n
      ldx = n
      Allocate (b(ldb,nrhs), e(n-1), ef(n-1), work(n), x(ldx,nrhs), &
        berr(nrhs), d(n), df(n), ferr(nrhs), rwork(n))

!     Read the lower bidiagonal part of the tridiagonal matrix A and
!     the right hand side b from data file

      Read (nin, *) d(1:n)
      Read (nin, *) e(1:n-1)
      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Solve the equations AX = B for X
      Call zptsvx('Not factored', n, nrhs, d, e, df, ef, b, ldb, x, ldx, &
        rcond, ferr, berr, work, rwork, info)

      If ((info==0) .Or. (info==n+1)) Then

!       Print solution, error bounds and condition number

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
          x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
          'Integer', clabs, 80, 0, ifail)

        Write (nout, *)
        Write (nout, *) 'Backward errors (machine-dependent)'
        Write (nout, 100) berr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
        Write (nout, 100) ferr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimate of reciprocal condition number'
        Write (nout, 100) rcond

        If (info==n+1) Then
          Write (nout, *)
          Write (nout, *) 'The matrix A is singular to working precision'
        End If
      Else
        Write (nout, 110) 'The leading minor of order ', info, &
          ' is not positive definite'
      End If

100   Format (1X, 1P, 7E11.1)
110   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks