概要
本サンプルはFortran言語によりLAPACKルーチンZPPSVXを利用するサンプルプログラムです。
以下の式を解きます。
はエルミート正定値行列です。
及び
解のエラー推定値、均衡化についての情報、スケーリングされた行列
の条件数の逆数の推定値も合わせて出力されます。
入力データ
（本ルーチンの詳細はZPPSVX のマニュアルページを参照）| このデータをダウンロード |
ZPPSVX Example Program Data
4 2 :Values of N and NRHS
( 3.23, 0.00) ( 1.51, -1.92) ( 1.90, 0.84) ( 0.42, 2.50)
( 3.58, 0.00) (-0.23, 1.11) (-1.18, 1.37)
( 4.09, 0.00) ( 2.33, -0.14)
( 4.29, 0.00) :End of matrix A
( 3.93, -6.14) ( 1.48, 6.58)
( 6.17, 9.42) ( 4.65, -4.75)
(-7.17,-21.83) (-4.91, 2.29)
( 1.99,-14.38) ( 7.64,-10.79) :End of matrix B
出力結果
（本ルーチンの詳細はZPPSVX のマニュアルページを参照）| この出力例をダウンロード |
ZPPSVX Example Program Results
Solution(s)
1 2
1 ( 1.0000,-1.0000) (-1.0000, 2.0000)
2 (-0.0000, 3.0000) ( 3.0000,-4.0000)
3 (-4.0000,-5.0000) (-2.0000, 3.0000)
4 ( 2.0000, 1.0000) ( 4.0000,-5.0000)
Backward errors (machine-dependent)
1.1E-16 7.9E-17
Estimated forward error bounds (machine-dependent)
6.1E-14 7.4E-14
Estimate of reciprocal condition number
6.6E-03
A has not been equilibrated
ソースコード
（本ルーチンの詳細はZPPSVX のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program zppsvx_example
! ZPPSVX Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
Use lapack_interfaces, Only: zppsvx
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: uplo = 'U'
! .. Local Scalars ..
Real (Kind=dp) :: rcond
Integer :: i, ifail, info, j, ldb, ldx, n, nrhs
Character (1) :: equed
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: afp(:), ap(:), b(:, :), work(:), &
x(:, :)
Real (Kind=dp), Allocatable :: berr(:), ferr(:), rwork(:), s(:)
Character (1) :: clabs(1), rlabs(1)
! .. Executable Statements ..
Write (nout, *) 'ZPPSVX Example Program Results'
Write (nout, *)
Flush (nout)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, nrhs
ldb = n
ldx = n
Allocate (afp((n*(n+1))/2), ap((n*(n+1))/2), b(ldb,nrhs), work(2*n), x( &
ldx,nrhs), berr(nrhs), ferr(nrhs), rwork(n), s(n))
! Read the upper or lower triangular part of the matrix A from
! data file
If (uplo=='U') Then
Read (nin, *)((ap(i+(j*(j-1))/2),j=i,n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ap(i+((2*n-j)*(j-1))/2),j=1,i), i=1, n)
End If
! Read B from data file
Read (nin, *)(b(i,1:nrhs), i=1, n)
! Solve the equations AX = B for X
Call zppsvx('Equilibration', uplo, n, nrhs, ap, afp, equed, s, b, ldb, &
x, ldx, rcond, ferr, berr, work, rwork, info)
If ((info==0) .Or. (info==n+1)) Then
! Print solution, error bounds, condition number and the form
! of equilibration
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
'Integer', clabs, 80, 0, ifail)
Write (nout, *)
Write (nout, *) 'Backward errors (machine-dependent)'
Write (nout, 100) berr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
Write (nout, 100) ferr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimate of reciprocal condition number'
Write (nout, 100) rcond
Write (nout, *)
If (equed=='N') Then
Write (nout, *) 'A has not been equilibrated'
Else If (equed=='Y') Then
Write (nout, *) &
'A has been row and column scaled as diag(S)*A*diag(S)'
End If
If (info==n+1) Then
Write (nout, *)
Write (nout, *) 'The matrix A is singular to working precision'
End If
Else
Write (nout, 110) 'The leading minor of order ', info, &
' is not positive definite'
End If
100 Format ((3X,1P,7E11.1))
110 Format (1X, A, I3, A)
End Program