複素線形方程式: 対称正定値行列 : (右辺はベクトル)

LAPACKサンプルソースコード : 使用ルーチン名：ZPOSV

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > 対称正定値行列

概要

本サンプルはFortran言語によりLAPACKルーチンZPOSVを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A x = b, \end{displaymath}

$ A$は対称正定値行列です。

\begin{displaymath} A = \left( \begin{array}{cccc} 3.23 & 1.51 - 1.92 i & 1.9... ...i & -1.18 - 1.37 i & 2.33 + 0.14 i & 4.29 \end{array} \right) \end{displaymath}

及び

\begin{displaymath} b = \left( \begin{array}{c} 3.93 - 6.14 i \\ 6.17 + 9.4... ...\\ -7.17 - 21.83 i \\ 1.99 - 14.38 i \end{array} \right). \end{displaymath}

$ A$のコレスキー分解についての詳細も合わせて出力されます。

入力データ

（本ルーチンの詳細はZPOSV のマニュアルページを参照）
このデータをダウンロード 
ZPOSV Example Program Data
   4                                                         :Value of N
 ( 3.23,  0.00) ( 1.51, -1.92) ( 1.90,  0.84) ( 0.42,  2.50)
                ( 3.58,  0.00) (-0.23,  1.11) (-1.18,  1.37)
                               ( 4.09,  0.00) ( 2.33, -0.14)
                                              ( 4.29,  0.00) :End of matrix A
 ( 3.93, -6.14) ( 6.17,  9.42) (-7.17,-21.83) ( 1.99,-14.38) :End of vector b

出力結果

（本ルーチンの詳細はZPOSV のマニュアルページを参照）
この出力例をダウンロード 
 ZPOSV Example Program Results

 Solution
    ( 1.0000,-1.0000) (-0.0000, 3.0000) (-4.0000,-5.0000) ( 2.0000, 1.0000)

 Cholesky factor U
                    1                 2                 3                 4
 1  ( 1.7972, 0.0000) ( 0.8402,-1.0683) ( 1.0572, 0.4674) ( 0.2337, 1.3910)
 2                    ( 1.3164, 0.0000) (-0.4702,-0.3131) ( 0.0834,-0.0368)
 3                                      ( 1.5604, 0.0000) ( 0.9360,-0.9900)
 4                                                        ( 0.6603, 0.0000)

ソースコード

（本ルーチンの詳細はZPOSV のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zposv_example

!     ZPOSV Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zposv
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, n
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), b(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZPOSV Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n
      lda = n
      Allocate (a(lda,n), b(n))

!     Read the upper triangular part of A from data file

      Read (nin, *)(a(i,i:n), i=1, n)

!     Read b from data file

      Read (nin, *) b(1:n)

!     Solve the equations Ax = b for x
      Call zposv('Upper', n, 1, a, lda, b, n, info)

      If (info==0) Then

!       Print solution

        Write (nout, *) 'Solution'
        Write (nout, 100) b(1:n)

!       Print details of factorization

        Write (nout, *)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('Upper', &
          'Non-unit diagonal', n, n, a, lda, 'Bracketed', 'F7.4', &
          'Cholesky factor U', 'Integer', rlabs, 'Integer', clabs, 80, 0, &
          ifail)

      Else
        Write (nout, 110) 'The leading minor of order ', info, &
          ' is not positive definite'
      End If

100   Format ((3X,4(' (',F7.4,',',F7.4,')',:)))
110   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks