概要
本サンプルはFortran言語によりLAPACKルーチンZPBSVXを利用するサンプルプログラムです。
以下の式を解きます。
はエルミート正定値帯行列です。
及び
解のエラー推定値、均衡化についての情報、スケーリングされた行列
の条件数の逆数の推定値も合わせて出力されます。
入力データ
（本ルーチンの詳細はZPBSVX のマニュアルページを参照）| このデータをダウンロード |
ZPBSVX Example Program Data
4 1 2 :Values of N, KD and NRHS
( 9.39, 0.00) ( 1.08,-1.73)
( 1.69, 0.00) ( -0.04, 0.29)
( 2.65, 0.00) ( -0.33, 2.24)
( 2.17, 0.00) :End of matrix A
(-12.42,68.42) (54.30,-56.56)
( -9.93, 0.88) (18.32, 4.76)
(-27.30,-0.01) (-4.40, 9.97)
( 5.31,23.63) ( 9.43, 1.41) :End of matrix B
出力結果
（本ルーチンの詳細はZPBSVX のマニュアルページを参照）| この出力例をダウンロード |
ZPBSVX Example Program Results
Solution(s)
1 2
1 (-1.0000, 8.0000) ( 5.0000,-6.0000)
2 ( 2.0000,-3.0000) ( 2.0000, 3.0000)
3 (-4.0000,-5.0000) (-8.0000, 4.0000)
4 ( 7.0000, 6.0000) (-1.0000,-7.0000)
Backward errors (machine-dependent)
1.0E-16 1.1E-16
Estimated forward error bounds (machine-dependent)
3.6E-14 3.4E-14
Estimate of reciprocal condition number
7.6E-03
A has not been equilibrated
ソースコード
（本ルーチンの詳細はZPBSVX のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program zpbsvx_example
! ZPBSVX Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
Use lapack_interfaces, Only: zpbsvx
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: uplo = 'U'
! .. Local Scalars ..
Real (Kind=dp) :: rcond
Integer :: i, ifail, info, j, kd, ldab, ldafb, ldb, ldx, n, nrhs
Character (1) :: equed
! .. Local Arrays ..
Complex (Kind=dp), Allocatable :: ab(:, :), afb(:, :), b(:, :), work(:), &
x(:, :)
Real (Kind=dp), Allocatable :: berr(:), ferr(:), rwork(:), s(:)
Character (1) :: clabs(1), rlabs(1)
! .. Intrinsic Procedures ..
Intrinsic :: max, min
! .. Executable Statements ..
Write (nout, *) 'ZPBSVX Example Program Results'
Write (nout, *)
Flush (nout)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, kd, nrhs
ldab = kd + 1
ldafb = kd + 1
ldb = n
ldx = n
Allocate (ab(ldab,n), afb(ldafb,n), b(ldb,nrhs), work(3*n), x(ldx,nrhs), &
berr(nrhs), ferr(nrhs), rwork(n), s(n))
! Read the upper or lower triangular part of the band matrix A
! from data file
If (uplo=='U') Then
Read (nin, *)((ab(kd+1+i-j,j),j=i,min(n,i+kd)), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ab(1+i-j,j),j=max(1,i-kd),i), i=1, n)
End If
! Read B from data file
Read (nin, *)(b(i,1:nrhs), i=1, n)
! Solve the equations AX = B for X
Call zpbsvx('Equilibration', uplo, n, kd, nrhs, ab, ldab, afb, ldafb, &
equed, s, b, ldb, x, ldx, rcond, ferr, berr, work, rwork, info)
If ((info==0) .Or. (info==n+1)) Then
! Print solution, error bounds, condition number and the form
! of equilibration
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
'Integer', clabs, 80, 0, ifail)
Write (nout, *)
Write (nout, *) 'Backward errors (machine-dependent)'
Write (nout, 100) berr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
Write (nout, 100) ferr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimate of reciprocal condition number'
Write (nout, 100) rcond
Write (nout, *)
If (equed=='N') Then
Write (nout, *) 'A has not been equilibrated'
Else If (equed=='Y') Then
Write (nout, *) &
'A has been row and column scaled as diag(S)*A*diag(S)'
End If
If (info==n+1) Then
Write (nout, *)
Write (nout, *) 'The matrix A is singular to working precision'
End If
Else
Write (nout, 110) 'The leading minor of order ', info, &
' is not positive definite'
End If
100 Format ((3X,1P,7E11.1))
110 Format (1X, A, I3, A)
End Program