複素線形方程式: エルミート行列 : (右辺は行列)

LAPACKサンプルソースコード : 使用ルーチン名：ZHESVX

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > エルミート行列

概要

本サンプルはFortran言語によりLAPACKルーチンZHESVXを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A X = B, \end{displaymath}

$ A$はエルミート行列です。

\begin{displaymath} A = \left( \begin{array}{cccc} -1.84 & 0.11 - 0.11 i & -1... ...i & 2.21 - 0.21 i & 1.58 + 0.90 i & -1.36 \end{array} \right) \end{displaymath}

及び

\begin{displaymath} B = \left( \begin{array}{cc} 2.98 - 10.18 i & 28.68 - 39.... ... i \\ 7.79 + 5.48 i & -35.39 + 18.01 i \end{array} \right). \end{displaymath}

解のエラー推定値、行列$ A$の条件数の逆数の推定値も合わせて出力されます。

入力データ

（本ルーチンの詳細はZHESVX のマニュアルページを参照）
このデータをダウンロード 
ZHESVX Example Program Data
    4               2                                            :N and NRHS
 ( -1.84,  0.00) (  0.11, -0.11) ( -1.78, -1.18) (  3.91, -1.50)
                 ( -4.63 , 0.00) ( -1.84,  0.03) (  2.21,  0.21)
                                 ( -8.87,  0.00) (  1.58, -0.90)
                                                 ( -1.36 , 0.00) :End matrix A
 (  2.98,-10.18) ( 28.68,-39.89)
 ( -9.58,  3.88) (-24.79, -8.40)
 ( -0.77,-16.05) (  4.23,-70.02)
 (  7.79,  5.48) (-35.39, 18.01)                                 :End matrix B

出力結果

（本ルーチンの詳細はZHESVX のマニュアルページを参照）
この出力例をダウンロード 
 ZHESVX Example Program Results

 Solution(s)
                    1                 2
 1  ( 2.0000, 1.0000) (-8.0000, 6.0000)
 2  ( 3.0000,-2.0000) ( 7.0000,-2.0000)
 3  (-1.0000, 2.0000) (-1.0000, 5.0000)
 4  ( 1.0000,-1.0000) ( 3.0000,-4.0000)

 Backward errors (machine-dependent)
       5.1E-17    5.9E-17

 Estimated forward error bounds (machine-dependent)
       2.5E-15    3.0E-15

 Estimate of reciprocal condition number
       1.5E-01

ソースコード

（本ルーチンの詳細はZHESVX のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zhesvx_example

!     ZHESVX Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zhesvx
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=dp) :: rcond
      Integer :: i, ifail, info, lda, ldaf, ldb, ldx, lwork, n, nrhs
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), af(:, :), b(:, :), work(:), &
        x(:, :)
      Real (Kind=dp), Allocatable :: berr(:), ferr(:), rwork(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZHESVX Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      lda = n
      ldaf = n
      ldb = n
      ldx = n
      lwork = nb*n
      Allocate (a(lda,n), af(ldaf,n), b(ldb,nrhs), work(lwork), x(ldx,nrhs), &
        berr(nrhs), ferr(nrhs), rwork(n), ipiv(n))

!     Read the upper triangular part of A from data file

      Read (nin, *)(a(i,i:n), i=1, n)

!     Read B from data file

      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Solve the equations AX = B for X
      Call zhesvx('Not factored', 'Upper', n, nrhs, a, lda, af, ldaf, ipiv, b, &
        ldb, x, ldx, rcond, ferr, berr, work, lwork, rwork, info)

      If ((info==0) .Or. (info==n+1)) Then

!       Print solution, error bounds and condition number

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
          x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
          'Integer', clabs, 80, 0, ifail)

        Write (nout, *)
        Write (nout, *) 'Backward errors (machine-dependent)'
        Write (nout, 100) berr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
        Write (nout, 100) ferr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimate of reciprocal condition number'
        Write (nout, 100) rcond
        Write (nout, *)

        If (info==n+1) Then
          Write (nout, *)
          Write (nout, *) 'The matrix A is singular to working precision'
        End If
      Else
        Write (nout, 110) 'The diagonal block ', info, ' of D is zero'
      End If

100   Format ((3X,1P,7E11.1))
110   Format (1X, A, I3, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks