複素線形方程式: 一般行列 : (右辺は行列)

LAPACKサンプルソースコード : 使用ルーチン名：ZGESVX

ホーム > LAPACKサンプルプログラム目次 > 複素線形方程式 > 一般行列

概要

本サンプルはFortran言語によりLAPACKルーチンZGESVXを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A X = B, \end{displaymath}

$ A$は一般行列です。

\begin{displaymath} A = \left( \begin{array}{cccc} -1.34 + 2.55 i & 0.28 + 3.... ... 1.47 i & -0.83 - 0.69 i & -1.96 + 0.67 i \end{array} \right) \end{displaymath}

及び

\begin{displaymath} B = \left( \begin{array}{cc} 26.26 + 51.78 i & 31.32 - 6.... ...19 i \\ 1.16 + 2.57 i & -2.56 + 7.55 i \end{array} \right). \end{displaymath}

解のエラー推定値、スケーリングについての情報、スケーリングされた行列$ A$の条件数の逆数の推定値、$ A$の分解においての軸要素成長乗数の逆数の推定値も合わせて出力されます。

入力データ

（本ルーチンの詳細はZGESVX のマニュアルページを参照）
このデータをダウンロード 
ZGESVX Example Program Data

   4               2                                   :Values of N and NRHS

 (-1.34,  2.55) (  0.28,  3.17) (-6.39,-2.20) ( 0.72,-0.92)
 (-1.70,-14.10) ( 33.10, -1.50) (-1.50,13.40) (12.90,13.80)
 (-3.29, -2.39) ( -1.91,  4.42) (-0.14,-1.35) ( 1.72, 1.35)
 ( 2.41,  0.39) ( -0.56,  1.47) (-0.83,-0.69) (-1.96, 0.67) :End of matrix A

 (26.26, 51.78) ( 31.32, -6.70)
 (64.30,-86.80) (158.60,-14.20)
 (-5.75, 25.31) ( -2.15, 30.19)
 ( 1.16,  2.57) ( -2.56,  7.55)                             :End of matrix B

出力結果

（本ルーチンの詳細はZGESVX のマニュアルページを参照）
この出力例をダウンロード 
 ZGESVX Example Program Results

 Solution(s)
                    1                 2
 1  ( 1.0000, 1.0000) (-1.0000,-2.0000)
 2  ( 2.0000,-3.0000) ( 5.0000, 1.0000)
 3  (-4.0000,-5.0000) (-3.0000, 4.0000)
 4  ( 0.0000, 6.0000) ( 2.0000,-3.0000)

 Backward errors (machine-dependent)
       5.3E-17    4.8E-17

 Estimated forward error bounds (machine-dependent)
       5.8E-14    7.4E-14

 A has been row scaled as diag(R)*A

 Reciprocal condition number estimate of scaled matrix
       1.0E-02

 Estimate of reciprocal pivot growth factor
       8.3E-01

ソースコード

（本ルーチンの詳細はZGESVX のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program zgesvx_example

!     ZGESVX Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_complex_gen_comp
      Use lapack_interfaces, Only: zgesvx
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=dp) :: rcond
      Integer :: i, ifail, info, lda, ldaf, ldb, ldx, n, nrhs
      Character (1) :: equed
!     .. Local Arrays ..
      Complex (Kind=dp), Allocatable :: a(:, :), af(:, :), b(:, :), work(:), &
        x(:, :)
      Real (Kind=dp), Allocatable :: berr(:), c(:), ferr(:), r(:), rwork(:)
      Integer, Allocatable :: ipiv(:)
      Character (1) :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout, *) 'ZGESVX Example Program Results'
      Write (nout, *)
      Flush (nout)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, nrhs
      lda = n
      ldaf = n
      ldb = n
      ldx = n
      Allocate (a(lda,n), af(ldaf,n), b(ldb,nrhs), work(2*n), x(ldx,nrhs), &
        berr(nrhs), c(n), ferr(nrhs), r(n), rwork(2*n), ipiv(n))

!     Read A and B from data file

      Read (nin, *)(a(i,1:n), i=1, n)
      Read (nin, *)(b(i,1:nrhs), i=1, n)

!     Solve the equations AX = B for X

      Call zgesvx('Equilibrate', 'No transpose', n, nrhs, a, lda, af, ldaf, &
        ipiv, equed, r, c, b, ldb, x, ldx, rcond, ferr, berr, work, rwork, &
        info)

      If ((info==0) .Or. (info==n+1)) Then

!       Print solution, error bounds, condition number, the form
!       of equilibration and the pivot growth factor

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_complex_gen_comp('General', ' ', n, nrhs, &
          x, ldx, 'Bracketed', 'F7.4', 'Solution(s)', 'Integer', rlabs, &
          'Integer', clabs, 80, 0, ifail)

        Write (nout, *)
        Write (nout, *) 'Backward errors (machine-dependent)'
        Write (nout, 100) berr(1:nrhs)
        Write (nout, *)
        Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
        Write (nout, 100) ferr(1:nrhs)
        Write (nout, *)
        If (equed=='N') Then
          Write (nout, *) 'A has not been equilibrated'
        Else If (equed=='R') Then
          Write (nout, *) 'A has been row scaled as diag(R)*A'
        Else If (equed=='C') Then
          Write (nout, *) 'A has been column scaled as A*diag(C)'
        Else If (equed=='B') Then
          Write (nout, *) &
            'A has been row and column scaled as diag(R)*A*diag(C)'
        End If
        Write (nout, *)
        Write (nout, *) &
          'Reciprocal condition number estimate of scaled matrix'
        Write (nout, 100) rcond
        Write (nout, *)
        Write (nout, *) 'Estimate of reciprocal pivot growth factor'
        Write (nout, 100) rwork(1)

        If (info==n+1) Then
          Write (nout, *)
          Write (nout, *) 'The matrix A is singular to working precision'
        End If
      Else
        Write (nout, 110) 'The (', info, ',', info, ')', &
          ' element of the factor U is zero'
      End If

100   Format ((3X,1P,7E11.1))
110   Format (1X, A, I3, A, I3, A, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks