計算ルーチン: 実三角行列の逆行列 : (Rectangular Full Packed フォーマット)

DTFTRI Example Program Data
  4       'L'   'N'   'N' : n, uplo, transr, diag
 -8.02   -5.95
  4.30    0.12
 -3.96   -4.87
  0.40    0.31
 -0.27    0.07            : AR

 DTFTRI Example Program Results

 Inverse
             1          2          3          4
 1      0.2326
 2     -0.1891    -0.2053
 3      0.0043    -0.0079    -0.1247
 4      0.8463    -0.2738    -6.1825     8.3333

    Program dtftri_example

!     DTFTRI Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
      Use lapack_interfaces, Only: dtftri, dtfttr
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, k, lar1, lda, lenar, n, q
      Character (1) :: diag, transr, uplo
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: a(:, :), ar(:)
!     .. Executable Statements ..
      Write (nout, *) 'DTFTRI Example Program Results'
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, uplo, transr, diag

      lenar = n*(n+1)/2
      lda = n
      Allocate (ar(lenar), a(lda,n))

!     Setup notional dimensions of RFP matrix AR
      k = n/2
      q = n - k
      If (transr=='N' .Or. transr=='n') Then
        lar1 = 2*k + 1
      Else
        lar1 = q
      End If

!     Read an RFP matrix into array AR
      Do i = 1, lar1
        Read (nin, *) ar(i:lenar:lar1)
      End Do

!     Compute inverse of A
      Call dtftri(transr, uplo, diag, n, ar, info)

      Write (nout, *)
      Flush (nout)
      If (info==0) Then

!       Convert inverse to full array form, and print it
        Call dtfttr(transr, uplo, n, ar, a, lda, info)
        ifail = 0
        Call nagf_file_print_matrix_real_gen(uplo, 'Nonunit', n, n, a, lda, &
          'Inverse', ifail)
      Else
        Write (nout, *) 'A is singular'
      End If

    End Program