実対称固有値問題: 対称行列 : (分割統治法)

LAPACKサンプルソースコード : 使用ルーチン名：DSYEVD

ホーム > LAPACKサンプルプログラム目次 > 実対称固有値問題 > 対称行列

概要

本サンプルはFortran言語によりLAPACKルーチンDSYEVDを利用するサンプルプログラムです。

対称行列のすべての固有値と固有ベクトルを求めます。

\begin{displaymath} A = \left( \begin{array}{rrrr} 1 & 2 & 3 & 4 \\ 2 & 2 &... ... 4 \\ 3 & 3 & 3 & 4 \\ 4 & 4 & 4 & 4 \end{array} \right). \end{displaymath}

DSYEVの例題プログラムは固有値と固有ベクトルの誤差限界計算方法を示します。

入力データ

（本ルーチンの詳細はDSYEVD のマニュアルページを参照）
このデータをダウンロード 
DSYEVD Example Program Data
  4                         :Value of N
  'L'                       :Value of UPLO
  1.0
  2.0   2.0
  3.0   3.0   3.0
  4.0   4.0   4.0   4.0     :End of matrix A
  'V'                       :Value of JOB

出力結果

（本ルーチンの詳細はDSYEVD のマニュアルページを参照）
この出力例をダウンロード 
 DSYEVD Example Program Results

 Eigenvalues
    -2.0531 -0.5146 -0.2943 12.8621

 Eigenvectors
          1       2       3       4
 1   0.7003 -0.5144 -0.2767  0.4103
 2   0.3592  0.4851  0.6634  0.4422
 3  -0.1569  0.5420 -0.6504  0.5085
 4  -0.5965 -0.4543  0.2457  0.6144

ソースコード

（本ルーチンの詳細はDSYEVD のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program dsyevd_example

!     DSYEVD Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_blas_damax_val, &
        nagf_file_print_matrix_real_gen
      Use lapack_interfaces, Only: dsyevd
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=dp), Parameter :: zero = 0.0_dp
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=dp) :: r
      Integer :: i, ifail, info, k, lda, liwork, lwork, n
      Character (1) :: job, uplo
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: a(:, :), w(:), work(:)
      Integer, Allocatable :: iwork(:)
!     .. Executable Statements ..
      Write (nout, *) 'DSYEVD Example Program Results'
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n
      lda = n
      liwork = 5*n + 3
      lwork = 2*n*n + 6*n + 1
      Allocate (a(lda,n), w(n), work(lwork), iwork(liwork))

!     Read A from data file

      Read (nin, *) uplo
      If (uplo=='U') Then
        Read (nin, *)(a(i,i:n), i=1, n)
      Else If (uplo=='L') Then
        Read (nin, *)(a(i,1:i), i=1, n)
      End If

      Read (nin, *) job

!     Calculate all the eigenvalues and eigenvectors of A
      Call dsyevd(job, uplo, n, a, lda, w, work, lwork, iwork, liwork, info)

      Write (nout, *)
      If (info>0) Then
        Write (nout, *) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout, *) 'Eigenvalues'
        Write (nout, 100) w(1:n)
        Write (nout, *)
        Flush (nout)

!       Normalize the eigenvectors: largest element positive
        Do i = 1, n
          Call nagf_blas_damax_val(n, a(1,i), 1, k, r)
          If (a(k,i)<zero) Then
            a(1:n, i) = -a(1:n, i)
          End If
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_real_gen('General', ' ', n, n, a, lda, &
          'Eigenvectors', ifail)

      End If

100   Format (3X, (8F8.4))
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks