概要
本サンプルはFortran言語によりLAPACKルーチンDSPSVXを利用するサンプルプログラムです。
以下の式を解きます。
は対称行列です。
解のエラー推定値、行列
の条件数の逆数の推定値も合わせて出力されます。
入力データ
（本ルーチンの詳細はDSPSVX のマニュアルページを参照）| このデータをダウンロード |
DSPSVX Example Program Data
4 2 :Values of N and NRHS
-1.81 2.06 0.63 -1.15
1.15 1.87 4.20
-0.21 3.87
2.07 :End of matrix A
0.96 3.93
6.07 19.25
8.38 9.90
9.50 27.85 :End of matrix B
出力結果
（本ルーチンの詳細はDSPSVX のマニュアルページを参照）| この出力例をダウンロード |
DSPSVX Example Program Results
Solution(s)
1 2
1 -5.0000 2.0000
2 -2.0000 3.0000
3 1.0000 4.0000
4 4.0000 1.0000
Backward errors (machine-dependent)
1.4E-16 1.0E-16
Estimated forward error bounds (machine-dependent)
2.5E-14 3.2E-14
Estimate of reciprocal condition number
1.3E-02
ソースコード
（本ルーチンの詳細はDSPSVX のマニュアルページを参照）※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
| このソースコードをダウンロード |
Program dspsvx_example
! DSPSVX Example Program Text
! Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com
! .. Use Statements ..
Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
Use lapack_interfaces, Only: dspsvx
Use lapack_precision, Only: dp
! .. Implicit None Statement ..
Implicit None
! .. Parameters ..
Integer, Parameter :: nin = 5, nout = 6
Character (1), Parameter :: uplo = 'U'
! .. Local Scalars ..
Real (Kind=dp) :: rcond
Integer :: i, ifail, info, j, ldb, ldx, n, nrhs
! .. Local Arrays ..
Real (Kind=dp), Allocatable :: afp(:), ap(:), b(:, :), berr(:), ferr(:), &
work(:), x(:, :)
Integer, Allocatable :: ipiv(:), iwork(:)
! .. Executable Statements ..
Write (nout, *) 'DSPSVX Example Program Results'
Write (nout, *)
Flush (nout)
! Skip heading in data file
Read (nin, *)
Read (nin, *) n, nrhs
ldb = n
ldx = n
Allocate (afp((n*(n+1))/2), ap((n*(n+1))/2), b(ldb,nrhs), berr(nrhs), &
ferr(nrhs), work(3*n), x(ldx,nrhs), ipiv(n), iwork(n))
! Read the upper or lower triangular part of the matrix A from
! data file
If (uplo=='U') Then
Read (nin, *)((ap(i+(j*(j-1))/2),j=i,n), i=1, n)
Else If (uplo=='L') Then
Read (nin, *)((ap(i+((2*n-j)*(j-1))/2),j=1,i), i=1, n)
End If
! Read B from data file
Read (nin, *)(b(i,1:nrhs), i=1, n)
! Solve the equations AX = B for X
Call dspsvx('Not factored', uplo, n, nrhs, ap, afp, ipiv, b, ldb, x, &
ldx, rcond, ferr, berr, work, iwork, info)
If ((info==0) .Or. (info==n+1)) Then
! Print solution, error bounds and condition number
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call nagf_file_print_matrix_real_gen('General', ' ', n, nrhs, x, ldx, &
'Solution(s)', ifail)
Write (nout, *)
Write (nout, *) 'Backward errors (machine-dependent)'
Write (nout, 100) berr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimated forward error bounds (machine-dependent)'
Write (nout, 100) ferr(1:nrhs)
Write (nout, *)
Write (nout, *) 'Estimate of reciprocal condition number'
Write (nout, 100) rcond
Write (nout, *)
If (info==n+1) Then
Write (nout, *)
Write (nout, *) 'The matrix A is singular to working precision'
End If
Else
Write (nout, 110) 'The diagonal block ', info, ' of D is zero'
End If
100 Format ((3X,1P,7E11.1))
110 Format (1X, A, I3, A)
End Program