計算ルーチン: DGEQRF または DGEQPF により決まる QR 分解からの直交 Q の全てまたは一部の生成

DORGQR Example Program Data
  6  4                        :Values of M and N
 -0.57  -1.28  -0.39   0.25
 -1.93   1.08  -0.31  -2.14
  2.30   0.24   0.40  -0.35
 -1.93   0.64  -0.66   0.08
  0.15   0.30   0.15  -2.13
 -0.02   1.03  -1.43   0.50   :End of matrix A

 DORGQR Example Program Results

 The leading  4 columns of Q
          1       2       3       4
 1  -0.1576  0.6744 -0.4571  0.4489
 2  -0.5335 -0.3861  0.2583  0.3898
 3   0.6358 -0.2928  0.0165  0.1930
 4  -0.5335 -0.1692 -0.0834 -0.2350
 5   0.0415 -0.1593  0.1475  0.7436
 6  -0.0055 -0.5064 -0.8339  0.0335

    Program dorgqr_example

!     DORGQR Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
      Use lapack_interfaces, Only: dgeqrf, dorgqr
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, lwork, m, n
      Character (30) :: title
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: a(:, :), tau(:), work(:)
!     .. Executable Statements ..
      Write (nout, *) 'DORGQR Example Program Results'
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) m, n
      lda = m
      lwork = 64*n
      Allocate (a(lda,n), tau(n), work(lwork))

!     Read A from data file

      Read (nin, *)(a(i,1:n), i=1, m)

!     Compute the QR factorization of A
      Call dgeqrf(m, n, a, lda, tau, work, lwork, info)

!     Form the leading N columns of Q explicitly
      Call dorgqr(m, n, n, a, lda, tau, work, lwork, info)

!     Print the leading N columns of Q only

      Write (nout, *)
      Write (title, 100) n
      Flush (nout)

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call nagf_file_print_matrix_real_gen('General', ' ', m, n, a, lda, &
        title, ifail)

100   Format ('The leading ', I2, ' columns of Q')
    End Program