計算ルーチン: DGEQLFの QL 分解の結果より : (直交 Q の一部または全てを取り出す)

DORGQL Example Program Data

  6      4                   :Values of M and N

 -0.57  -1.28  -0.39   0.25
 -1.93   1.08  -0.31  -2.14
  2.30   0.24   0.40  -0.35
 -1.93   0.64  -0.66   0.08
  0.15   0.30   0.15  -2.13
 -0.02   1.03  -1.43   0.50 :End of matrix A

 DORGQL Example Program Results

 The leading    4 columns of Q
          1       2       3       4
 1  -0.0833  0.9100 -0.2202 -0.0809
 2   0.2972 -0.1080 -0.2706  0.6922
 3  -0.6404 -0.2351  0.2220  0.1132
 4   0.4461 -0.1620 -0.3866 -0.0259
 5  -0.2938  0.2022  0.0015  0.6890
 6  -0.4575 -0.1946 -0.8243 -0.1617

    Program dorgql_example

!     DORGQL Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_real_gen
      Use lapack_interfaces, Only: dgeqlf, dorgql
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, lda, lwork, m, n
      Character (30) :: title
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: a(:, :), tau(:), work(:)
!     .. Executable Statements ..
      Write (nout, *) 'DORGQL Example Program Results'
      Write (nout, *)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) m, n
      lda = m
      lwork = nb*n
      Allocate (a(lda,n), tau(n), work(lwork))

!     Read A from data file

      Read (nin, *)(a(i,1:n), i=1, m)

!     Compute the QL factorization of A

      Call dgeqlf(m, n, a, lda, tau, work, lwork, info)

!     Form the leading N columns of Q explicitly

      Call dorgql(m, n, n, a, lda, tau, work, lwork, info)

!     Form the heading for nAGF_FILE_PRINT_MATRIX_REAL_GEN

      Write (title, 100) n
      Flush (nout)

!     Print the leading N columns of Q

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call nagf_file_print_matrix_real_gen('General', ' ', m, n, a, lda, &
        title, ifail)

100   Format ('The leading ', I4, ' columns of Q')
    End Program