実線形方程式: 帯行列 : (右辺はベクトル)

LAPACKサンプルソースコード : 使用ルーチン名：DGBSV

ホーム > LAPACKサンプルプログラム目次 > 実線形方程式 > 帯行列

概要

本サンプルはFortran言語によりLAPACKルーチンDGBSVを利用するサンプルプログラムです。

以下の式を解きます。

\begin{displaymath} A x = b, \end{displaymath}

$ A$は帯行列です。

\begin{displaymath} A = \left( \begin{array}{rrrr} -0.23 & 2.54 & -3.66 & 0 \... ...} 4.42 \\ 27.13 \\ -6.14 \\ 10.50 \end{array} \right). \end{displaymath}

$ A$の $ LU$分解についての詳細も合わせて出力されます。

入力データ

（本ルーチンの詳細はDGBSV のマニュアルページを参照）
このデータをダウンロード 
DGBSV Example Program Data

  4  1  2                     :Values of N, KL and KU

 -0.23   2.54  -3.66
 -6.98   2.46  -2.73  -2.13
         2.56   2.46   4.07
               -4.78  -3.82   :End of matrix A

  4.42  27.13  -6.14  10.50   :End of vector B

出力結果

（本ルーチンの詳細はDGBSV のマニュアルページを参照）
この出力例をダウンロード 
 DGBSV Example Program Results

 Solution
       -2.0000     3.0000     1.0000    -4.0000

 Details of factorization
             1          2          3          4
 1     -6.9800     2.4600    -2.7300    -2.1300
 2      0.0330     2.5600     2.4600     4.0700
 3                 0.9605    -5.9329    -3.8391
 4                            0.8057    -0.7269

 Pivot indices
             2          3          3          4

ソースコード

（本ルーチンの詳細はDGBSV のマニュアルページを参照）

※本サンプルソースコードのご利用手順は「サンプルのコンパイル及び実行方法」をご参照下さい。
このソースコードをダウンロード 
    Program dgbsv_example

!     DGBSV Example Program Text

!     Copyright 2017, Numerical Algorithms Group Ltd. http://www.nag.com

!     .. Use Statements ..
      Use lapack_example_aux, Only: nagf_file_print_matrix_real_band
      Use lapack_interfaces, Only: dgbsv
      Use lapack_precision, Only: dp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer :: i, ifail, info, j, k, kl, ku, ldab, n
!     .. Local Arrays ..
      Real (Kind=dp), Allocatable :: ab(:, :), b(:)
      Integer, Allocatable :: ipiv(:)
!     .. Intrinsic Procedures ..
      Intrinsic :: max, min
!     .. Executable Statements ..
      Write (nout, *) 'DGBSV Example Program Results'
      Write (nout, *)
!     Skip heading in data file
      Read (nin, *)
      Read (nin, *) n, kl, ku
      ldab = 2*kl + ku + 1
      Allocate (ab(ldab,n), b(n), ipiv(n))

!     Read the band matrix A and the right hand side b from data file

      k = kl + ku + 1
      Read (nin, *)((ab(k+i-j,j),j=max(i-kl,1),min(i+ku,n)), i=1, n)
      Read (nin, *) b(1:n)

!     Solve the equations Ax = b for x
      Call dgbsv(n, kl, ku, 1, ab, ldab, ipiv, b, n, info)

      If (info==0) Then

!       Print solution

        Write (nout, *) 'Solution'
        Write (nout, 100) b(1:n)

!       Print details of the factorization

        Write (nout, *)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call nagf_file_print_matrix_real_band(n, n, kl, kl+ku, ab, ldab, &
          'Details of factorization', ifail)

!       Print pivot indices'

        Write (nout, *)
        Write (nout, *) 'Pivot indices'
        Write (nout, 110) ipiv(1:n)

      Else
        Write (nout, 120) 'The (', info, ',', info, ')', &
          ' element of the factor U is zero'
      End If

100   Format ((3X,7F11.4))
110   Format ((3X,7I11))
120   Format (1X, A, I3, A, I3, A, A)
    End Program


ご案内
関連情報
Privacy Policy  /  Trademarks